本页包含 Google Ads 查询语言语法参考。如需详细了解查询结构，请参阅查询结构。
语法参考文档
以下是 Google Ads 查询语言的语法参考（采用正则表达式表示法）：
Query -> SelectClause FromClause? WhereClause? OrderByClause?
LimitClause? ParametersClause?
SelectClause -> SELECT FieldName ("," FieldName)*
FromClause -> FROM ResourceName
WhereClause -> WHERE Condition (AND Condition)*
OrderByClause -> ORDER BY Ordering ("," Ordering)*
LimitClause -> LIMIT PositiveInteger
ParametersClause -> PARAMETERS Literal "=" Value ("," Literal "=" Value)*
Condition -> FieldName IS NULL
| FieldName IS NOT NULL
| FieldName BETWEEN Value AND Value
| FieldName Operator Value
Operator -> "=" | "!=" | ">" | ">=" | "<" | "<=" | IN | NOT IN
| LIKE | NOT LIKE | CONTAINS ANY | CONTAINS ALL
| CONTAINS NONE | DURING
| REGEXP_MATCH | NOT REGEXP_MATCH
Value -> Literal | LiteralList | Number | NumberList | String
| StringList | Function
Ordering -> FieldName (ASC | DESC)?
FieldName -> [a-z]([a-zA-Z0-9._])*
ResourceName -> [a-z]([a-zA-Z0-9_])*
StringList -> "(" String ("," String)* ")"
LiteralList -> "(" Literal ("," Literal)* ")"
NumberList -> "(" Number ("," Number)* ")"
PositiveInteger -> [1-9]([0-9])*
Number -> -?[0-9]+(\.[0-9]+)?
String -> ("'" SingleQuoteChar* "'") | ('"' DoubleQuoteChar* '"')
SingleQuoteChar -> [^'\\\r\n] | EscapeSequence
DoubleQuoteChar -> [^"\\\r\n] | EscapeSequence
EscapeSequence -> "\\" ("\\" | "'" | '"' | "n" | "r" | "t")
Literal -> [a-zA-Z]([a-zA-Z0-9_])*
Function -> LAST_14_DAYS | LAST_30_DAYS | LAST_7_DAYS
| LAST_BUSINESS_WEEK | LAST_MONTH | LAST_WEEK_MON_SUN
| LAST_WEEK_SUN_SAT | THIS_MONTH | THIS_WEEK_MON_TODAY
| THIS_WEEK_SUN_TODAY | TODAY | YESTERDAY
?表示可选元素。*表示零个或多个；+表示一个或多个。(...)表示分组，而"("和")"表示文本圆括号。[a-z0-9]表示字符范围，[^...]表示除所列字符之外的任何字符。|表示“或”。
规则和限制
查询
GoogleAdsService时需要FromClause，查询GoogleAdsFieldService时 必须省略。WhereClause仅支持将条件与AND结合使用。不支持逻辑OR；请改用IN或REGEXP_MATCH运算符。REGEXP_MATCH运算符使用 RE2 语法。如需使用
LIKE运算符匹配字面值[、]、%或_，请将相应字符放在方括号中。例如，以下条件会匹配所有以[Earth_to_Mars]开头的campaign.name值：campaign.name LIKE '[[]Earth[_]to[_]Mars[]]%'LIKE运算符只能用于字符串字段，而不能用于数组。