Грамматика языка запросов Google Ads

На этой странице представлен справочник по грамматике языка запросов Google Ads. Подробную информацию о структуре запроса см. в разделе «Структура запроса» .

Справочник по грамматике

Вот справочник по грамматике языка запросов Google Ads (в ​​формате регулярных выражений):

Query            -> SelectClause FromClause? WhereClause? OrderByClause?
                    LimitClause? ParametersClause?
SelectClause     -> SELECT FieldName ("," FieldName)*
FromClause       -> FROM ResourceName
WhereClause      -> WHERE Condition (AND Condition)*
OrderByClause    -> ORDER BY Ordering ("," Ordering)*
LimitClause      -> LIMIT PositiveInteger
ParametersClause -> PARAMETERS Literal "=" Value ("," Literal "=" Value)*

Condition        -> FieldName IS NULL
                  | FieldName IS NOT NULL
                  | FieldName BETWEEN Value AND Value
                  | FieldName Operator Value
Operator         -> "=" | "!=" | ">" | ">=" | "<" | "<=" | IN | NOT IN
                  | LIKE | NOT LIKE | CONTAINS ANY | CONTAINS ALL
                  | CONTAINS NONE | DURING
                  | REGEXP_MATCH | NOT REGEXP_MATCH
Value            -> Literal | LiteralList | Number | NumberList | String
                  | StringList | Function
Ordering         -> FieldName (ASC | DESC)?

FieldName        -> [a-z]([a-zA-Z0-9._])*
ResourceName     -> [a-z]([a-zA-Z0-9_])*

StringList       -> "(" String ("," String)* ")"
LiteralList      -> "(" Literal ("," Literal)* ")"
NumberList       -> "(" Number ("," Number)* ")"

PositiveInteger  -> [1-9]([0-9])*
Number           -> -?[0-9]+(\.[0-9]+)?
String           -> ("'" SingleQuoteChar* "'") | ('"' DoubleQuoteChar* '"')
SingleQuoteChar  -> [^'\\\r\n] | EscapeSequence
DoubleQuoteChar  -> [^"\\\r\n] | EscapeSequence
EscapeSequence   -> "\\" ("\\" | "'" | '"' | "n" | "r" | "t")
Literal          -> [a-zA-Z]([a-zA-Z0-9_])*

Function         -> LAST_14_DAYS | LAST_30_DAYS | LAST_7_DAYS
                  | LAST_BUSINESS_WEEK | LAST_MONTH | LAST_WEEK_MON_SUN
                  | LAST_WEEK_SUN_SAT | THIS_MONTH | THIS_WEEK_MON_TODAY
                  | THIS_WEEK_SUN_TODAY | TODAY | YESTERDAY
  • ? указывает на необязательный элемент.
  • * означает ноль или более; + означает один или более.
  • (...) обозначает группировку, а "(" и ")" обозначают буквальные скобки.
  • [a-z0-9] обозначает диапазоны символов, а [^...] обозначает любой символ, кроме перечисленных.
  • | означает «или».

Правила и ограничения

  • FromClause обязателен при запросе GoogleAdsService и должен быть опущен при запросе GoogleAdsFieldService .

  • WhereClause поддерживает объединение условий только с помощью AND . Логическое OR не поддерживается; вместо него используйте оператор IN или REGEXP_MATCH .

  • Оператор REGEXP_MATCH использует синтаксис RE2 .

  • Чтобы сопоставить символ [ , ] , % или _ с помощью оператора LIKE , заключите его в квадратные скобки. Например, следующее условие соответствует всем значениям campaign.name , начинающимся с [Earth_to_Mars] :

    campaign.name LIKE '[[]Earth[_]to[_]Mars[]]%'

  • Оператор LIKE можно использовать только со строковыми полями, а не с массивами.

Назад
Обзор
Далее
Структура запроса